QT += quick qml quickcontrols2 sql multimedia

android {
    QT += androidextras
}

VERSION = 1.0.1
QMAKE_TARGET_PRODUCT = "ScStwApp"
QMAKE_TARGET_COMPANY = "Itsblue Development"
QMAKE_TARGET_COPYRIGHT = "Copyright (c) by Itsblue Development"

# Add to define
DEFINES += APP_VERSION=\"\\\"$${VERSION}\\\"\"

CONFIG += c++11

# The following define makes your compiler emit warnings if you use
# any feature of Qt which as been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

TARGET = ScStwApp

# include submodules
CONFIG += ScStwLibraries_QML ScStwLibraries_Styling ScStwLibraries_ClientLibs
include($$PWD/shared-libraries/ScStwLibraries/ScStwLibraries.pri)

SOURCES += \
    sources/scstwappbackend.cpp \
    sources/main.cpp \
    sources/scstwappsettings.cpp

HEADERS += \
    headers/scstwappbackend.h \
    headers/scstwappsettings.h

RESOURCES += \
             resources/shared/shared.qrc \
             resources/qml/qml.qrc

# Additional import path used to resolve QML modules in Qt Creator's code model
QML_IMPORT_PATH =

# Additional import path used to resolve QML modules just for Qt Quick Designer
QML_DESIGNER_IMPORT_PATH =

#Plugins
QTPLUGIN += qtaudio_coreaudio

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
#else: unix:!android: target.path = /opt/$${TARGET}/bin
else: unix:!android: target.path = /home/pi/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

DISTFILES += \
    CHANGELOG \
    android/AndroidManifest.xml \
    android/build.gradle \
    android/gradle.properties \
    android/gradle/wrapper/gradle-wrapper.jar \
    android/gradle/wrapper/gradle-wrapper.properties \
    android/gradlew \
    android/gradlew.bat \
    android/res/values/libs.xml \
    android/src/de/itsblue/scstw/MainActivity.java

android {
    ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
    defineReplace(droidVersionCode) {
            segments = $$split(1, ".")
            for (segment, segments): vCode = "$$first(vCode)$$format_number($$segment, width=3 zeropad)"

            contains(ANDROID_TARGET_ARCH, arm64-v8a): \
                suffix = 1
            else:contains(ANDROID_TARGET_ARCH, armeabi-v7a): \
                suffix = 0
            # add more cases as needed

            return($$first(vCode)$$first(suffix))
    }

    ANDROID_VERSION_NAME = $$VERSION
    ANDROID_VERSION_CODE = $$droidVersionCode($$ANDROID_VERSION_NAME)
}

# This has to be the last line in the file
ANDROID_ABIS = armeabi-v7a arm64-v8a