!isEmpty(SCSTWLIBRARIES_LIB):error("ScStwLibraries.pri already included")
SCSTWLIBRARIES_LIB = 1

QT += multimedia

ScStwLibraries_QML {
    QT += qml quickcontrols2
    DEFINES += ScStwLibraries_QML

    ScStwLibraries_Styling {
        DEFINES += ScStwLibraries_Styling
    }

}

ScStwLibraries_ClientLibs {
    DEFINES += ScStwLibraries_ClientLibs
}

INCLUDEPATH += $$PWD/headers $$PWD

SOURCES += \
    $$PWD/sources/ScStw.cpp \
    $$PWD/sources/scstwsoundplayer.cpp \
    $$PWD/sources/scstwlibraries.cpp \
    $$PWD/sources/scstwrace.cpp \
    $$PWD/sources/scstwtimer.cpp

HEADERS += \
    $$PWD/headers/ScStw.hpp \
    $$PWD/headers/ScStwLibraries_global.h \
    $$PWD/headers/scstwlibraries.h \
    $$PWD/headers/scstwrace.h \
    $$PWD/headers/scstwsoundplayer.h \
    $$PWD/headers/scstwtimer.h

ScStwLibraries_ClientLibs {
    SOURCES += \
        $$PWD/sources/client/scstwclient.cpp \
        $$PWD/sources/client/scstwremotemonitorrace.cpp

    HEADERS += \
        $$PWD/headers/client/scstwclient.h \
        $$PWD/headers/client/scstwremotemonitorrace.h

    INCLUDEPATH += $$PWD/headers/client
}

ScStwLibraries_QML {
    ScStwLibraries_Styling {
        SOURCES += \
            $$PWD/sources/styling/scstwapptheme.cpp \
            $$PWD/sources/styling/scstwappthememanager.cpp

        HEADERS += \
            $$PWD/headers/styling/scstwapptheme.h \
            $$PWD/headers/styling/scstwappthememanager.h

        RESOURCES += \
            $$PWD/resources/qml/ScStwStylingQml.qrc \
            $$PWD/resources/shared/ScStwStylingShared.qrc \

        INCLUDEPATH += $$PWD/headers/styling
    }
}

RESOURCES += \
    $$PWD/resources/shared/ScStwLibrariesShared.qrc