app/blueROCK.pro

QT += quick qml quickcontrols2 purchasing printsupport
CONFIG += c++11

VERSION = 0.5.0
TARGET = blueROCK

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Refer to the documentation for the
# deprecated API to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH *= $$PWD/headers

# Add version to define
DEFINES += APP_VERSION=\"\\\"$${VERSION}\\\"\"

SOURCES += \
    sources/shareUtils/platformshareutils.cpp \
    sources/appsettings.cpp \
    sources/bluerockbackend.cpp \
    sources/shareUtils/shareutils.cpp \
    sources/main.cpp

HEADERS += \
    headers/appsettings.h \
    headers/bluerockbackend.h \
    headers/shareUtils/shareutils.h \
    headers/shareUtils/platformshareutils.h

RESOURCES += resources/qml/qml.qrc \
    resources/shared/shared.qrc \
    #resources/shared/icons/bluerock/index.theme \
    #$$files(resources/shared/icons/*.png, true)


# Additional import path used to resolve QML modules in Qt Creator's code model
QML_IMPORT_PATH =

# Additional import path used to resolve QML modules just for Qt Quick Designer
QML_DESIGNER_IMPORT_PATH =

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

DISTFILES += \
    CHANGELOG.md

android {
    QT += androidextras

    SOURCES += sources/shareUtils/androidshareutils.cpp
    HEADERS += headers/shareUtils/androidshareutils.h

    OTHER_FILES += android/src/org/ekkescorner/utils/QShareUtils.java \
        android/src/org/ekkescorner/utils/QSharePathResolver.java \
        android/src/de/itsblue/blueROCK/MainActivity.java \
        android/AndroidManifest.xml \
        android/build.gradle \
        android/gradle.properties \
        android/gradle/wrapper/gradle-wrapper.jar \
        android/gradle/wrapper/gradle-wrapper.properties \
        android/gradlew \
        android/gradlew.bat \
        android/res/values/libs.xml \
        android/res/xml/filepaths.xml

    defineReplace(droidVersionCode) {
            segments = $$split(1, ".")
            for (segment, segments): vCode = "$$first(vCode)$$format_number($$segment, width=3 zeropad)"

            contains(ANDROID_TARGET_ARCH, arm64-v8a): \
                suffix = 1
            else:contains(ANDROID_TARGET_ARCH, armeabi-v7a): \
                suffix = 0
            # add more cases as needed

            return($$first(vCode)$$first(suffix))
    }

    ANDROID_VERSION_NAME = $$VERSION
    ANDROID_VERSION_CODE = $$droidVersionCode($$ANDROID_VERSION_NAME)
    message(Android version code: $$ANDROID_VERSION_CODE)

    include(/home/dorian/Android/Sdk/android_openssl/openssl.pri)
    ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
}

ios {
    QMAKE_ASSET_CATALOGS += resources/shared/Assets.xcassets
    xcode_product_bundle_identifier_setting.value = "de.itsblue.bluerock"
}

CONFIG += enable_decoder_qr_code \
          enable_encoder_qr_code \
          qzxing_multimedia \
          qzxing_qml
include(qzxing/src/QZXing-components.pri)

# this has to be the last line!
ANDROID_ABIS = armeabi-v7a arm64-v8a